%----------------------------------------------------------------
% 0. Housekeeping (close all graphic windows)
%----------------------------------------------------------------

close all;

%----------------------------------------------------------------
% 1. Defining variables
%----------------------------------------------------------------

var y c k i r z;
varexo e;

parameters beta delta alpha sigma rho sigma_a;

%----------------------------------------------------------------
% 2. Calibration
%----------------------------------------------------------------

alpha   = (1/3);
beta    = 0.95;
delta   = .05;
rho     = 0.85^(1/4); 
sigma_a   = .015 / (1+rho^2 + rho^4 + rho^6);
sigma = 1;


%----------------------------------------------------------------
% 3. Model
%----------------------------------------------------------------

model; 
  (c)^(-sigma) = beta*((c(+1)^(-sigma))*(r(+1)));
  r = alpha*exp(z)*(k(-1)^(alpha-1)) + (1-delta);
  c+i = y;
  y = exp(z)*(k(-1)^alpha);
  i = k-(1-delta)*k(-1);
  z = rho*z(-1)+e;

  
end;

%----------------------------------------------------------------
% 4. Computation
%----------------------------------------------------------------

initval;
  k = 5.7;
  c = 1.5;
  z = 0;
  e = 0; 
end;

shocks;
var e = sigma_a^2;

end;

steady;

stoch_simul(hp_filter = 1600, order = 1);

%----------------------------------------------------------------
% 5. Some Results
%----------------------------------------------------------------