#-*- encoding: iso-8859-1 -*-

define Stems [ {tukka}| {kakku} | {pappi} | {tippa} | {katto} | {juttu} |
               {tikka} | {huppu} | {rotta} | {nahka} |
               {lika} | {maku} | {rako} | {tuke} | {halko} | {jalka} | {virka}|
               {lanka} | {linko} | {puku} | {suku} | {tiuku} | {raaka} |
               {ripa} | {sopu} | {tapa} | {kampa} | {rumpu} | {sampe} |
               {sota} | {pata} | {kita} | {rinta} | {kanto} | {ranta} |
               {ilta} | {kulta} | {parta} | {kerta} ];

define Case  [ "+Part":a | "+Gen":n ];

define Finnish [Stems Case];

define V [a | e | i | o | u | y | ä | ö];
define C [b | c | d | f | g | h | j | k | l | m | n | p | q | r | s |
          t | v | w | x | z];

define Coda [ C  [C | .#.] ];


define WeakK  k -> ' || V a _ a Coda, V u _ u Coda 
                     .o.
              k -> j || r _ e Coda
                     .o.
              k -> v || u _ u Coda
                     .o.
              k -> g || n _ V Coda
                     .o.
              k -> 0 || \[s|h] _ V Coda ;  # kiskon 'rail', nahkan 'skin'

define WeakP  p -> m || m _ V Coda
                     .o.
              p -> v || \[s|p] _ V Coda    # piispan 'bishop'
                     .o.
              p -> 0 || p _ V Coda;

define WeakT  t -> n || n _ V Coda
                     .o.
              t -> l || l _ V Coda
                     .o.
              t -> r || r _ V Coda
                     .o.
              t -> d || \[s|t] _ V Coda    # koston 'revenge'
                     .o.
              t -> 0 || t _ V Coda ;


define Gradation  WeakK .o. WeakP .o. WeakT;

regex Finnish .o. Gradation;

print lower-words

echo *** Size of Finnish .o. Gradation
print size
echo *** Size of Finnish
push Finnish
print size
echo *** Size of Gradation
push Gradation
print size