Multichar_Symbols +Noun +Adj +NSuff +ASuff +Nize
                +Pl +Sg +Acc MF+
                +Aug +Dim +Fem Op+ Neg+

LEXICON Root
        Nouns ;
        Adjectives ;

LEXICON Nouns
        NounRoots ;
MF+:ge  NounRoots ;     ! optional ge prefix 
                        !    ("male and female")

LEXICON NounRoots       ! noun roots
bird    Nmf ;        
hund    Nmf ;
kat     Nmf ;
elefant Nmf ;

LEXICON Nmf
+Noun:0 AugDimFem ;

LEXICON AugDimFem
+Fem:in AugDimFem ;     ! feminine; note the loop back to 
                        !    AugDimFem
+Dim:et AugDimFem ;     ! diminutive; note the loop
+Aug:eg AugDimFem ;     ! augmentative; note the loop
        Nend ;          ! escape path to Nend
        Adjend ;        ! escape path to Adjend for
                        !  derivation of noun to adjective

LEXICON Nend
+NSuff:o  Number ;      ! required noun suffix

LEXICON Adjectives
        AdjPrefixes ;   ! start with a prefix 
        AdjRoots ;      ! or an adjective root

LEXICON AdjPrefixes
Op+:mal AdjRoots ;
Neg+:ne AdjRoots ;

LEXICON AdjRoots        ! adjective roots
bon     Adj ;
long    Adj ;
jun     Adj ;
alt     Adj ;
grav    Adj ;

LEXICON Adj
+Adj:0  AugDimNize ;

LEXICON AugDimNize      ! looped
+Aug:eg AugDimNize ;    ! augmentative
+Dim:et AugDimNize ;    ! diminutive
        Adjend ;        ! escape to Adjend
+Nize:ec   Nend ;       ! escape to Nend for derivation
                        !  of adjective to noun

LEXICON Adjend
+ASuff:a   Number ;     ! required adjective suffix

LEXICON Number
+Pl:j   Case ;          ! optional plural suffix
+Sg:0   Case ;

LEXICON Case
+Acc:n  # ;             ! optional accusative-case 
                        ! suffix
        # ;