DEMO   ENGLISH   CONFIG (1.0)
  ROOTCAT   S.
  LEXENTRIES  (DEMO ENGLISH).
  RULES       (DEMO ENGLISH).
  TEMPLATES   (DEMO ENGLISH).
  GOVERNABLERELATIONS    SUBJ OBJ COMP OBL OBJ2.
  SEMANTICFUNCTIONS    ADJUNCT.
  NONDISTRIBUTIVES.


----

DEMO   ENGLISH   RULES (1.0)


   S --> (ADV: ! $ (^ ADJUNCT))
	 NP: (^ SUBJ)=!
	     (! CASE)=nom;
 	 { VP
 	  |VPaux}.

   VP --> V
 	  (NP: (^ OBJ)=!
	       (! CASE)=acc)
	  (NP: (^ OBJ2)=!
	       (! CASE)=acc)
 	  (PP: (^ OBL)=!) "obliques precede adjuncts"
 	  { ADV: ! $ (^ ADJUNCT)
 	   |PP:! $ (^ ADJUNCT)}*.

   VPaux --> AUX
	     VP.

   NP --> (D)
	  AP*: ! $ (^ ADJUNCT);
 	  N
 	  PP*:! $ (^ ADJUNCT).

   PP --> P
	  NP:(^ OBJ)=!
	     (! CASE)=acc.

   AP --> A.

----
DEMO-PLUS ENGLISH RULES (1.0)



----
DEMO   ENGLISH   TEMPLATES (1.0)

   NOUN-SG(_P) = "template for singular nouns"
	  @(PRED _P)
	  @(NUM sg).

   PRED(_P) = "basic PRED with no arguments"
	  (^ PRED)='_P'.

   NUM(_V) = "assigns value to number feature"
	  (^ NUM)=_V.

   UP-OBJ = "annotation to assign object function"
	  
	  @(UP-GF OBJ).

   UP-GF(_GF) = "generic annotation to assign a grammatical function"
	  
	  (^ _GF)=!.

----
DEMO ENGLISH LEXICON (1.0)

is 	  AUX * (^ TENSE)=pres
	        (^ SUBJ NUM) =c sg
	        (^ SUBJ PERS)=  3
		(^ ASPECT)=prog.

in 	  P *   (^ PRED)='in<(^ OBJ)>'
	        (^ OBJ PCASE)=in.

with 	  P *   (^ PRED)='with<(^ OBJ)>'
	        (^ OBJ PCASE)=with.

about 	  P * (^ PRED)='about<(^ OBJ)>'
	      (^ OBJ PCASE)=about.

the 	  D *   (^ SPEC)=def.

a 	  D *   (^ SPEC)=indef
	        (^ NUM)=sg.

an 	  D *   (^ SPEC)=indef
	        (^ NUM)=sg.

girl 	  N *   (^ PRED)='girl'
	        (^ NUM)=sg.

girls 	  N *   (^ PRED)='girl'
	        (^ NUM)=pl.

monkey    N *   (^ PRED)='monkey'
	        (^ NUM)=sg.

banana 	  N *   (^ PRED)='banana'
	        (^ NUM)=sg.

orange 	  N * @(NOUN-SG orange);
	  A * (^ PRED)='orange'.

telescope N *   (^ PRED)='telescope'
	        (^ NUM)=sg.

park      N *   (^ PRED)='park'
	        (^ NUM)=sg.

garden      N *   (^ PRED)='garden'
	        (^ NUM)=sg.

sheep 	  N * (^ PRED)='sheep'
	      { (^ NUM)=sg | (^ NUM)=pl}.

devours   V *   (^ PRED)='devour<(^ SUBJ)(^ OBJ)>'
	        (^ SUBJ NUM) =c sg
	        (^ SUBJ PERS)=  3
                (^ TENSE)=pres. 

devouring  V *   (^ PRED)='devour<(^ SUBJ)(^ OBJ)>'
	        (^ ASPECT)=c prog.


devoured  V *   (^ PRED)='devour<(^ SUBJ)(^ OBJ)>'
                (^ TENSE)=past.

saw 	  V *   (^ PRED)='see<(^ SUBJ)(^ OBJ)>'
                (^ TENSE)=past.

sees 	  V *   (^ PRED)='see<(^ SUBJ)(^ OBJ)>'
	        (^ SUBJ NUM) =c sg
	        (^ SUBJ PERS)=  3
                (^ TENSE)=pres.

gives V *   (^ PRED)='give<(^ SUBJ)(^ OBJ)(^ OBJ2)>'
	        (^ SUBJ NUM) =c sg
	        (^ SUBJ PERS)=  3
                (^ TENSE)=pres.

gave V *   (^ PRED)='give<(^ SUBJ)(^ OBJ)(^ OBJ2)>'
                (^ TENSE)=past.

giving 	  V * (^ PRED)='give<(^ SUBJ)(^ OBJ)(^ OBJ2)>'
	      (^ ASPECT)=c prog.

laughed   V *   (^ PRED)='laugh<(^ SUBJ)>'
                (^ TENSE)=past.

laughs   V *   (^ PRED)='laugh<(^ SUBJ)>'
	        (^ SUBJ NUM) =c sg
	        (^ SUBJ PERS)=  3
                (^ TENSE)=pres.

laughing   V *   (^ PRED)='laugh<(^ SUBJ)>'
                (^ ASPECT)=c prog.

sleeping  V *   (^ PRED)='sleep<(^ SUBJ)>'
	        (^ ASPECT)=c prog.

sleeps 	  V *   (^ PRED)='sleep<(^ SUBJ)>'
	        (^ SUBJ NUM) =c sg
	        (^ SUBJ PERS)=  3
                (^ TENSE)=pres.

thought   V * (^ PRED)='about<(^ SUBJ)(^ OBL)>'
	      (^ OBL OBJ PCASE)=c about
	      (^ TENSE)=past.

yesterday ADV * (^ PRED)='yesterday'.

today ADV * (^ PRED)='today'.

purple A * (^ PRED)='purple'.

----

DEMO-PLUS ENGLISH LEXICON (1.0)


----